Warning

This wiki is very out of date, and only exists for historical reasons. For more modern information, see the new documentation and cookbook forum.

renpy/doc/translations/Belarusian the question

From Ren'Py Visual Novel Engine

Jump to: navigation, search

Pierakład dla 6.10.0

Heta pierakład fajłu the_question/game/script.rpy, zamianice kantent Vašaha fajłu na hety. Nie zabyvajćiesia pra kadoŭcu UTF-8.

# Apisannie vyjaŭ dla karystannia ŭ hulnie.
image bg lecturehall = "lecturehall.jpg"
image bg uni = "uni.jpg"
image bg meadow = "meadow.jpg"
image bg club = "club.jpg"

image sylvie normal = "sylvie_normal.png"
image sylvie giggle = "sylvie_giggle.png"
image sylvie smile = "sylvie_smile.png"
image sylvie surprised = "sylvie_surprised.png"    

image sylvie2 normal = "sylvie2_normal.png"
image sylvie2 giggle = "sylvie2_giggle.png"
image sylvie2 smile = "sylvie2_smile.png"  
image sylvie2 surprised = "sylvie2_surprised.png"    

# Apisańnie čaraktaraŭ
define s = Character(u'Sylvija', color="#c8ffc8")
define m = Character(u'Ja', color="#c8c8ff")

# Hulnia pačynajecca tut.
label start:
    $ bl_game = False
    
    play music "illurock.ogg"

    scene bg lecturehall
    with fade

    "Liekcyja prafesara Eileen była vielmi cikavaj."
    "Ale kali być siumliennym, ja byj niedastatkova ŭvažlivym na joj. "
    "U miane było šmat druhich dumak."
    "I usie jany zakančvaliś adzinym pytanniem."
    "Pytanniem, jakoje ja zadam kalisci."

    scene bg uni
    with fade

    "Kali my vyjšli z universiteta, ja ŭbačyŭ jaje."
    
    show sylvie normal
    with dissolve
    
    "Jana była vielmi pryhožaj."
    "Ja viedaŭ jaje kali my byli jaščie dziećmi."
    "I jana zaŭsiody była maim dobrym siabram."
    "Ale..."
    "Adnojčy..."
    "Ja padumaŭ..."
    "... što chočacca bolš."
    "Bolš za maŭliennie... bolš čym prosta špacyravać dadomu razam paslia urokaŭ."
    "I ja vyrašyŭ..."

    menu:

        "... kazać joj zaraz.":
        
            jump rightaway
            
        "... kazać joj potym.":
        
            jump later
       

label rightaway:

    show sylvie smile

    m"Vitaju, davaj špacyrujem dadomu razam?"
    s"Davaj..."
    "Kazaŭ ja dryhujučym hołasam."
    
    scene bg meadow
    with fade
    
    "My dajšli da łuha za horadam."
    "Voseń tut bačycca vielmi pryhoža."
    "Kali my byli dziecmi, my huliali tut."
    m "Hej... ummm..."
    
    show sylvie smile
    with dissolve
    
    "Jana zviarnułaś da mianie."
    "Ja spytaju jaje..."
    m "Mmm... Ty..."
    m "Ty nie žadaješ być artystam dlia majoj vizualnaj naveły?"
    
    show sylvie surprised
    
    "Maŭklivasć."
    "Jana była ŭ šoku. I tady..."
    
    show sylvie smile
    
    s "Kaniešnie, ale što takoje \"vizualnaja naveła?\""

    menu:

        "Historyja z vyjavami.":
            jump vn
            
        "Heta hentai hulnia.":
            jump hentai

label vn:

    m "Heta historyja z vyjavami z muzycaj."
    m "I ty maieš machčymasc utvarać svaje varyjanty adjazu."
    s "Heta jak abiary-svoj-lios kniha?"
    m "Tak! U mianie josć płan pa stvarenniu ramantyčnaj vuzualnaj naveły."
    m "I ja ličy to budzieš zdolna mnie dapamachčy... ja viedaju, ty kachaješ maliavannie."
    
    show sylvie normal
    
    s "Ja pasprabuju. Spadziajusia što nie zasapsuju ciabie."
    m "Ty viedaješ, ty nie možaš mianie sapsavać."

    jump marry
    
label hentai:

    $ bl_game = True
    
    m "Heta hulnia z vialikaj doliaj seksu."
    s "Maješ na uvazie, mužčynskaja hulnia?"
    s "Ja zaŭsiody žadała zrabić takuju hulniu."
    s "Dobra! Davaj pačniem!"

    hide sylvie
    with dissolve

    "..."

    m "Heta nie toje što ja mieŭ na ŭvazie!"

    jump marry
    
label marry:
    
    scene black
    with dissolve

    "--- praz hod ---"

    scene bg club
    with dissolve

    "Paslia, my stvaryli kamandu stvaralnikaŭ vizualnych naveł."
    "My raspracoŭvali hulni i atrymlivali zadavalniennie ad usiacho hetaha."

    if bl_game:
        "Akramia taho, u niekatoraj časci Mužyckaj Hulni jana pryniała udzieł."

    "I Adnojčy..."
        
    show sylvie2 normal
    with dissolve
        
    s "Hej..."    
    m "Tak?"
    
    show sylvie2 giggle
    
    s "Ažanisia na mnie!"
    m "ŠO???"
    
    show sylvie2 surprised
    
    s "Ty nie kachaješ mianie?"
    m "Kachaju viadoma."
    
    show sylvie2 smile
    
    s "Bačyš? My stvarali vuzualnyja naveły, pravodzili razam čas, dapamahali adzin adnamu...."
    s "... i kali ty daryš kachannie inšym, jano prychodzić i da ciabie."
    m "Mmm, pryhožaje vykazvannie."

    show sylvie2 giggle
    
    s "Ja tolki zrabiła jaho."
    m "Ale heta vydatna."
    
    show sylvie2 normal
    
    s "Ja viedaju. Dyk ty budzieš žanicca na mnie?"
    m "Mmm, viadoma. Ja sam žadaŭ prapanavać heta, ale ty była pieršaj..."
    s "Ja viedaju, ale ty taki nierašučy. Tamu ja prajaviła inicyjatyvu. "
    m "Viadoma... Heta usio pra pytannie ŭ nieabchodny čas... jak zaraz."
    
    show sylvie2 giggle
    
    s "Viadoma. Ale zaraz spyni hety teoryju - daj mnie pacałunak!"

    scene black
    with dissolve

    "My vielmi chutka ažanilisia paslia hetaj padziei."
    "Paslia my zrabili vielmi mnoha naveł."
    "I razam, my žyviem ščasliva na sionniašni čas."

    ".:. Dobraja kancoŭka."

    return
    
label later:

    scene black
    with dissolve

    "Ja vyrašyŭ spytać pazniej."
    "Ale ja vielmi nierašučy..."
    "Ja nie zmoh spytać jaje tady, nie zmoh spytać jaje potym."
    "Ja viedaju, što nie spytaju nikoli."
    
    ".:. Drennaja Kancoŭka."
    
    return
Personal tools