# Этот файл содержит код, демонстрирующий работу со слоями и продвинутое отображение.

init:

    # Объявляем слой 'demo', расположенный перед слоем по умолчанию, 'master'
    $ config.layers.insert(1, 'demo')

    # Делаем так, чтобы он занимал только часть экрана.
    $ config.layer_clipping['demo'] = (50, 50, 700, 500)


label demo_layers:

    e "Ren'Py позволяет создавать слои и показывать нужные изображения в нужном слое."

    hide eileen
    with dissolve

    show bg whitehouse onlayer demo
    with dissolve

    show eileen happy onlayer demo 
    with dissolve

    e "Приписка \"{i}onlayer{/i}\" к командам {i}scene{/i}, {i}show{/i}, и {i}hide{/i} позволяет задавать, к какому слою команда относится."

    e "Как видите, слои не обязательно должны быть размером с весь экран. Когда слой по размерам меньше, изображение обрезается, чтобы влезть."

    scene onlayer demo
    show eileen happy
    with dissolve

    e "Приписка \"{i}as{/i}\" позволяет давать изображению новый ярлык."

    show eileen happy as eileen2
    with None

    show eileen happy at left
    show eileen happy at right as eileen2
    with move

    e "Удобно, когда нужно показать две копии одного и того же изображения."

    e "Или у персонажа есть близнец."

    show eileen happy at center
    show eileen happy at offscreenright as eileen2
    with move

    hide eileen2

    show expression Text(u"Это - текст.", size=50, yalign=0.5, xalign=0.5, drop_shadow=(2, 2)) as text
    with dissolve

    e "Можно использовать \"{i}show{/i} что-то\" для отобажения не только изображений, но и, например, текста."

    hide text
    with dissolve

    show logo base at Position(xalign=0.6, yalign=0.0) behind eileen
    with dissolve

    e "Наконец, приписка \"{i}behind{/i}\" позволяет располагать новое изображение позади старого."

    hide logo base
    show eileen happy
    with dissolve

    e "Это всё, что я хотела рассказать о слоях и продвинутом отображении."

    return
