# В этом файле находится демонстрация режима NVL.

init:

    # Объявляем nvl-версию Эйлин.
    $ nvle = Character(u"Эйлин", color="#c8ffc8", kind=nvl)
    
    # Эффекты перехода от одного режима к другому
    $ config.adv_nvl_transition = dissolve
    $ config.nvl_adv_transition = dissolve
    
    # А это объявляет комментатора NVL-персонажем. Нам большую часть времени нужен АDV-комментатор, поэтому мы это закомментили.
#    $ narrator = NVLCharacter(None, kind=nvl)

label demo_nvlmode:

    nvl clear
    nvl show dissolve

    nvle "Игры NVL-стиля - игры, в которых текстовое окно занимает весь экран, а не ютится внизу эрана, как в играх ADV-стиля."

    nvle "Ren'Py поставляется с файлом nvl_mode.rpy, который определяет стили для NVL-игр. Вы видите пример работы режима NVL."

    nvl clear
    
    nvle "Для работы в режиме NVL нужно объявить персонажа (объект Character) с аргументом {i}kind=nvl{/i}."

    nvle "Для очистки экрана, когда это необходимо, используется команда {i}nvl clear{/i}."

    nvl hide dissolve
    nvl show dissolve

    nvle "Команды {i}nvl show{/i} и {i}nvl hide{/i} используют эффекты перехода для показа и скрытия NVL-окна ."

    nvle "Функция {i}nvl_erase{/i} убирает последнюю реплику с экрана."

    $ nvl_erase()

    nvle "Вот так."
    
    # Делать так по ходу игры не рекомендуется, лучше это было сделать
    # в блоке init. Нам пришлось сделать это здесь, так как нам нужны
    # оба вида меню.
    $ menu = nvl_menu
    
    menu:

        nvle "Режим {i}nvl_mode{/i} также поддерживает меню, главное чтобы они были последней вещью, выводимой на данный экран. Понятно?"

        "Да.":

            nvl clear

            nvle "Вот и хорошо!"

            nvl clear
            
        "Нет.":

            nvl clear

            nvle "Ну, может, если заглянете в код, это поможет Вам разобраться."

            nvl clear
            
    eside "Вы можете определять эффекты перехода из режима NVL в режим ADV."

    nvle "И из режима ADV в режим NVL."

    nvle "Тэги, вроде {{w}{w}, также работают в режиме NVL. "

    extend " Как и особый персонаж \"extend\"."

    nvle "Это всё, что я хотела рассказать о режиме NVL."
    
    $ menu = renpy.display_menu

    nvl hide dissolve
    
    return
        
    
