# Этот файл содержит демонстрацию работы с персонажами (объектами Character)
# для изменения вида вывода текста.

init:
    # С вложенным индикатором "нажми-для-продолжения".
    $ ectc = Character(u'Эйлин',
                       color="#c8ffc8",
                       ctc=anim.Blink("arrow.png"))


    # С индикатором "нажми-для-продолжения" на фиксированной позиции.
    $ ectcf = Character(u'Эйлин',
                        color="#c8ffc8",
                        ctc=anim.Filmstrip("sakura.png", (20, 20), (2, 1), .30, xpos=760, ypos=560, xanchor=0, yanchor=0),
                        ctc_position="fixed")

    # С двоеточием после имени и кавычками по сторонам текста.
    $ equote = Character(u'Эйлин',
                         color="#c8ffc8",
                         who_suffix = ':',
                         what_prefix='"',
                         what_suffix='"')

    # Странно выглядящий.
    $ eweird = Character(u'Эйлин',
                         color="#c8ffc8",
                         what_underline=True,
                         window_left_margin=200,
                         window_yminimum=300)

    # В режиме двух текстовых окон.
    $ etwo = Character(u'Эйлин',
                       color="#c8ffc8",
                       show_two_window=True)

    # С изображением.
    $ eside = Character(u'Эйлин',
                        color="#c8ffc8",
                        window_left_padding=160,
                        show_side_image=Image("eileen_side.png", xalign=0.0, yalign=1.0))

label demo_character:


    e "Объект персонажа ({i}Character{/i}) служит для объявления персонажей и может быть использован для изменения вида произнесенных этим персонажем реплик."

    e "Применяя соответствующие аргументы, можно совершенно преобразить вид игры."

    e "Сейчас мы покажем некоторые возможности настройки персонажа."

    equote "Используя аргументы {i}what_prefix{/i} и {i}what_suffix{/i}, можно автоматически добавлять символы перед и после текста реплики."

    equote "Это проще, чем расставлять все эти кавычки вручную."

    equote "Также можно использовать {i}who_prefix{/i} and {i}who_suffix{/i} для добавления символов к имени персонажа."

    e "У объекта {i}Character{/i} есть аргументы, управляющие видом имени персонажа, текста его реплик и самого текстового окна."

    eweird "Так можно сииильно поменять внешний вид игры."

    eside "Более практичный путь для использования этого - в связке с {i}show_side_image{/i}, что позволяет расположить изображение рядом с текстом."

    etwo "Ещё есть {i}show_two_window{/i}, выносящий имя персонажа в собственное окошко."

    ectc "Наконец, продемонстрируем индикатор \"нажми для продолжения\". В данном примере он вложен в текст."

    ectcf "А в данном - расположен в фиксированном положении."

    e "Есть ещё многое, чего можно достичь с использованием объекта {i}Character{/i}, так как он управляет свойствами стиля всего отображаемого текста."

    e "Наконец, я продемонстрирую парочку особых предопределённых персонажей."

    show black
    with dissolve

    centered "Персонаж \"centered\" выводит текст по центру экрана, без текстового окна."

    centered "Это просто особым образом настроенный обычный персонаж. Очень удобен для вывода дат и заглавий."
    
    hide black
    with dissolve

    e "Персонаж \"extend\" - особенный."

    e "Он позволяет"

    show eileen vhappy

    extend " продолжить предыдущую реплику"

    show eileen happy

    extend " дополнительным текстом."

    e "Это позволяет менять что-либо посреди фразы. Если Вы не заметили, я меняла выражение лица."

    e "Надеюсь, эти персонажи, вместе с теми, что Вы создадите сами, помогут Вам создать игру Вашей мечты."
    
    return
